Microphone.silenceTimeOut

Доступность

Flash Player 6.

Синтаксис

active_mic.silenceTimeOut:Number

Описание

Свойство, доступное только для чтения; числовая величина, отражающая число миллисекунд между моментом, когда микрофон перестает различать звук и вызовом Microphone.onActivity(false. Значение по умолчанию — 2000 (2 секунды).

Для просмотра значения используйте Microphone.setSilenceLevel().

Пример

В примере ниже пользователю позволяется определить промежуток времени между моментом, когда микрофон прекращает различать звук и вызовом Microphone.onActivity(false). Пользователь задает это значение при помощи компонента NumericStepper, названного silenceTimeOut_nstep. Компонент ProgressBar с именем silenceLevel_pb меняет свое поведение в зависимости от того, считается ли аудиопоток тишиной. Если нет, компонент отображает уровень активности аудиопотока.

var silenceLevel_pb:mx.controls.ProgressBar;
var silenceTimeOut_nstep:mx.controls.NumericStepper;

this.createEmptyMovieClip("sound_mc", this.getNextHighestDepth());
var active_mic:Microphone = Microphone.get();
sound_mc.attachAudio(active_mic);

silenceLevel_pb.label = "Уровень активности: %3";
silenceLevel_pb.mode = "manual";
silenceTimeOut_nstep.minimum = 0;
silenceTimeOut_nstep.maximum = 10;
silenceTimeOut_nstep.value = active_mic.silenceTimeOut/1000;

var nstepListener:Object = new Object();
nstepListener.change = function (evt:Object) {
  active_mic.setSilenceLevel(active_mic.silenceLevel, evt.target.value*1000);
};
silenceTimeOut_nstep.addEventListener("change", nstepListener);

this.onEnterFrame = function() {
  silenceLevel_pb.setProgress(active_mic.activityLevel, 100);
};
active_mic.onActivity = function (active:Boolean) {
  if (active) {
    silenceLevel_pb.indeterminate = false;
    silenceLevel_pb.setStyle("themeColor", "haloGreen");
    silenceLevel_pb.label = "Уровень активности: %3";
  } else {
    silenceLevel_pb.indeterminate = true;
    silenceLevel_pb.setStyle("themeColor", "0xFF0000");
    silenceLevel_pb.label = "Уровень активности: (inactive)";
  }
};

См. также

Microphone.setSilenceLevel()

Посмотреть комментарии LiveDocs

Предыдущая | Следующая | Оглавление